cursos:ensamblador:lenguaje_4

Lenguaje Ensamblador del Z80 (IV)


Este capítulo se centra en una de las estructuras más importantes del microprocesador Z80: la pila (o Stack en inglés).

La pila es una porción de memoria donde se pueden almacenar valores de 16 bits, apilados uno a continuación del siguiente.

Su nombre viene del hecho que los datos se almacenan unos “encima” de los otros, como, por ejemplo, en una pila de platos.

Cuando almacenamos un nuevo plato en una pila, lo dejamos en la parte superior de la misma, sobre el plato anterior. Cuando queremos coger un plato, cogemos el plato de arriba, el situado en la parte superior de la pila.

Es lo que se conoce como una estructura de datos “tipo LIFO” (“Last In, First Out”): el último que entró es el primero que sale. En nuestro ejemplo de los platos, efectivamente cuando retiramos un plato extraemos el que está arriba del todo, por lo que el primero en salir (First Out) es el último que habíamos dejado (Last In).

En una pila de ordenador (como en nuestra pila de datos) sólo podemos trabajar con el dato que está arriba del todo de la pila: no podemos extraer uno de los platos intermedios. Sólo podemos apilar un dato nuevo y desapilar el dato apilado arriba del todo de la pila.

La pila del Spectrum no es de platos sino de valores numéricos de 16 bits. Introducimos valores y sacamos valores mediante 2 instrucciones concretas: PUSH <valor> y POP <valor>, donde normalmente <valor> será un registro (metemos en la pila el valor que contiene un registro de 16 bits, o bien leemos de la pila un valor y lo asignamos a un registro de 16 bits).

Por ejemplo, podemos guardar el valor que contiene un registro en la pila si tenemos que hacer operaciones con ese registro para así luego recuperarlo tras realizar una determinada tarea:

    ld bc, 1000
    push bc         ; Guardamos el contenido de BC en la pila
 
    ld bc, 2000
    (...)           ; Operamos con BC
 
    ld hl, 0
    add hl, bc      ; y ya podemos guardar el resultado de la operación
                    ; (recordemos que no existe "ld hl, bc", de modo que
                    ; lo almacenamos como HL = 0+BC
 
    pop bc          ; Hemos terminado de trabajar con BC, ahora
                    ; recuperamos el valor que tenia BC (1000).

La instrucción push bc introduce en memoria, en lo alto de la pila, el valor contenido en BC (1000), que recuperamos posteriormente con el pop bc.

La realidad es que el Spectrum no tiene una zona de memoria especial o aislada de la RAM dedicada a la pila. En su lugar se utiliza la misma RAM del Spectrum (0-65535).

El Z80 tiene un registro conocido como SP (Stack Pointer), o puntero de pila, que es un registro de 16 bits que contiene una dirección de memoria. Esa dirección de memoria es “la cabeza de la pila”: apunta al próximo lugar donde almacenaremos un dato.

La peculiaridad de la pila del Spectrum es que crece hacia abajo, en lugar de hacia arriba. Veamos un ejemplo práctico:


Cómo crece y decrece la pila del Z80

Veámoslo con un ejemplo:

Supongamos que SP (puntero de pila) apunta a 65535 y que tenemos los siguientes valores en BC y DE:

    ld bc, $00ff
    ld de, $aabb
    ld sp, 65535     ; Puntero de pila al final de la memoria

(Nota: como veremos más adelante, para poner la pila al final de la memoria en realidad hay que ponerla en $0000, pero por motivos didácticos y para simplificar la explicación, vamos a hacer este ejemplo con ese valor).

Si ahora hacemos:

    push bc          ; Apilamos el registro BC

Lo que estaremos haciendo es:

SP = SP - 2 = 65533
(SP) = BC = $00ff

Con lo que el contenido de la memoria sería:

      Celdilla    Contenido
     -----------------------
       65534         $ff
SP ->  65533         $00

Si a continuación hacemos otro PUSH:

    push de          ; Apilamos el registro DE

Lo que estaremos haciendo es:

SP = SP - 2 = 65531
(SP) = DE = $aabb

Con lo que el contenido de las celdillas de memoria sería:

      Celdilla    Contenido
     -----------------------
       65534         $ff
       65533         $00
       65532         $aa
SP ->  65531         $bb

Si ahora hacemos un POP:

    pop de

Lo que hacemos es:

DE = (SP) = $aabb
SP = SP + 2 = 65533

Y la memoria queda, de nuevo, como:

      Celdilla    Contenido
     -----------------------
       65534         $ff
SP ->  65533         $00

Como podemos ver, PUSH apila valores, haciendo decrecer el valor de SP, mientras que pop recupera valores, haciendo crecer (en 2 bytes, 16 bits) el valor de SP.

Con el objetivo de que el ejemplo fuera más comprensible, hemos establecido SP a 65535, pero si te fijas, después del primer PUSH se han guardado los valores en 65534 y 65533 (no hemos escrito nada en 65535). En realidad, lo que deberíamos hacer para aprovechar la memoria es poner SP a 0, ya que la primera operación que se hace es el decremento y después la escritura.

Por eso, poniendo SP = 0, el decremento en 2 unidades al hacer el PUSH produciría que los 2 valores se guardasen en 65534 y 65535, aprovechando así ese último byte de la memoria.


Así pues, podemos hacer PUSH y POP de los siguientes registros:

  • PUSH: AF, BC, DE, HL, IX, IY
  • POP : AF, BC, DE, HL, IX, IY

Lo que hacen PUSH y POP, tal y como funciona la pila, es:

push xx :
     SP  = SP-2
    (SP) = xx

pop xx :
    xx   = (SP)
    SP   = SP+2

Visto en “pseucódigo BASIC”, ambos comandos serían:

push hl  =   LET SP = SP-2
             POKE (SP+1), H
             POKE SP, L
 
pop hl   =   LET L = PEEK SP
             LET H = PEEK (SP+1)
             LET SP = SP+2

Nótese cómo la pila se decrementa ANTES de poner los datos en ella, y se incrementa DESPUES de sacar datos de la misma. Esto mantiene siempre SP apuntando al TOS (Top Of Stack).

                        Flags
   Instrucción       |S Z H P N C|
 ----------------------------------
 pop xx              |- - - - - -|
 push xx             |- - - - - -|

Nótese que también podemos apilar y desapilar AF. De hecho, es una forma de manipular los bits del registro F (hacer push bc con un valor determinado, por ejemplo, y hacer un pop af).


La pila resulta muy útil para gran cantidad de tareas en programas en ensamblador. Veamos algunos ejemplos:


  • Uno de sus usos más evidentes es el de preservar valores de registros mientras ejecutamos porciones de código. Supongamos que tenemos un registro cuyo valor queremos mantener, pero que tenemos que ejecutar una porción de código que lo modifica. Gracias a la pila podemos hacer lo siguiente:


    push bc          ; Guardamos el valor de BC
 
    (código)         ; Hacemos operaciones que necesitan usar BC
 
    pop bc           ; Recuperamos el valor que teníamos en BC

Esto incluye, por ejemplo, el almacenaje del valor de BC en los bucles cuando necesitamos operador con B, C o BC:

    ld a, 0
    ld b, 100
 
bucle:
    push bc          ; Guardamos BC
    ld b, 1
    add a, b
    pop bc           ; Recuperamos BC
    djnz bucle

En este sentido, también podremos anidar 2 o más bucles que usen el registro B o BC con PUSHes y POPs entre ellos. Supongamos un bucle BASIC del tipo:

For i=0 TO 20:
    FOR J=0 TO 100:
        CODIGO
    NEXT J
NEXT I

En ensamblador podríamos hacer:

    ld b, 20                 ; repetimos bucle externo 20 veces
 
bucle_externo:
    push bc                  ; Nos guardamos el valor de BC
    ld b, 100                ; Iteraciones del bucle interno
 
bucle_interno:
    (... código ...)
    djnz bucle_interno       ; FOR J=0 TO 100
    pop bc                   ; Recuperamos el valor de B
 
    djnz bucle_externo       ; For i=0 TO 20

Hay que tener en cuenta que PUSH y POP implican escribir en memoria (en la dirección apuntada por SP), por que siempre serán más lentas que guardarse el valor actual de B en otro registro:

    ld b, 20                 ; repetimos bucle externo 20 veces
 
bucle_externo:
    ld d, b                  ; Nos guardamos el valor de B
 
    ld b, 100                ; Iteraciones del bucle interno
 
bucle_interno:
    (... código ...)         ; En este codigo no podemos usar D
    djnz bucle_interno       ; FOR J=0 TO 100
 
    ld b, d                  ; Recuperamos el valor de B
    djnz bucle_externo       ; For i=0 TO 20

No obstante, en múltiples casos nos quedaremos sin registros libres donde guardar datos, por lo que la pila es una gran opción. No hay que obsesionarse con no usar la pila porque implique escribir en memoria. A menos que estemos hablando de una rutina muy muy crítica, que se ejecute muchas veces por cada fotograma de nuestro juego, PUSH y POP serán las mejores opciones para preservar valores, con un coste de 11 t-estados para el PUSH y 10 t-estados para el POP de los registros de propósito general y de 15 y 14 t-estados cuando trabajamos con IX e IY.


  • Como veremos en el próximo apartado, la pila es la clave de las subrutinas (CALL/RET) en el Spectrum (equivalente al GOSUB/RETURN de BASIC).


  • Almacenaje de datos de entrada y salida en subrutinas: Podemos pasar parámetros a nuestras rutinas apilándolos en el stack, de forma que nada más entrar en la rutina leamos de la pila esos parámetros. Además, cuando realicemos funciones en ensamblador embebidas dentro de otros lenguajes (por ejemplo, dentro de programas en C con Z88DK), recibiremos así dentro de nuestro bloque en ensamblador los parámetros pasados con llamadas de funciones C.


  • Para manipular el registro F: La instrucción pop af es la principal forma de manipular el registro F directamente (haciendo PUSH de otro registro y luego un pop af).
    push af
    pop bc        ; Ahora tenemos en C el contenido de los Flags


  • El puntero de pila se puede utilizar también (como veremos más adelante en código más avanzado) para escribir (PUSH) o leer (POP) dos bytes de golpe con una única instrucción, permitiendo escribir por ejemplo rutinas de impresión de gráficos mucho más eficientes.


  • Intercambiar valores de registros mediante PUSH y POP. Por ejemplo, para intercambiar el valor de BC y de DE:
    ; Simulando "EX DE, BC"
 
    push bc          ; Apilamos BC
    push de          ; Apilamos DE
    pop bc           ; Desapilamos BC
                     ; ahora BC=(valor apilado en push de)
    pop de           ; Desapilamos DE
                     ; ahora DE=(valor apilado en push bc)

Hemos usado el código anterior para ilustrar la posibilidad de intercambiar valores de registros usando exclusivamente la pila, aunque el siguiente código (que también la usa) es bastante más eficiente ya que la pareja PUSH/POP requiere 11+10 = 21 ciclos de reloj mientras que los dos LD cuestan apenas 4 ciclos de reloj:

    ; Simulando "ex de, bc"
    push hl
    ld l, c
    ld h, b
    pop bc

No sólo podemos intercambiar valores usando 2 PUSH y 2 POP sino que también existen las siguientes instrucciones de intercambio (EX) que permiten manipular el contenido de la pila:

ex (sp), hl
ex (sp), ix
ex (sp), iy

Con estas instrucciones podemos simular instrucciones que no existen en el Z80, como EX BC, HL, EX BC, IX, EX BC, IY, y otras combinaciones con diferentes registros.

Por ejemplo, supongamos que queremos intercambiar el valor del registro BC con el del registro IX, sin usar dos PUSH/POP ni instrucciones LD de 8 bits:

    push bc
    ex (sp), ix    ; IX = el valor de BC
    pop bc         ; BC = el valor de IX

Las siguientes instrucciones podrían ser simuladas con este método:

Instrucción incorrecta Alternativa
ex bc, hl push bc
ex (sp), hl
pop bc
ex bc, ix push bc
ex (sp), ix
pop bc
ex bc, iy push bc
ex (sp), iy
pop bc
ex af, hl push af
ex (sp), hl
pop af
ex af, ix push af
ex (sp), ix
pop af
ex af, iy push af
ex (sp), iy
pop af
ex de, ix push de
ex (sp), ix
pop de
ex de, iy push de
ex (sp), iy
pop de


Pero como todo arma, las pilas también tienen un doble filo. Mal utilizada puede dar lugar a enormes desastres en nuestros programas.

Veamos algunos de los más habituales:


  • Dado que la pila decrece en memoria, tenemos que tener cuidado con el valor de SP y la posición más alta de memoria donde hayamos almacenado datos o rutinas. Si ponemos un gráfico o una rutina cerca del valor inicial de SP, y realizamos muchas operaciones de PUSH, podemos sobreescribir nuestros datos con los valores que estamos apilando.
  • Hacer más PUSH que POP o más POP que PUSH. Recordemos que la pila tiene que ser consistente. Si hacemos un PUSH, debemos recordar hacer el pop correspondiente (a menos que haya una razón para ello), y viceversa. Como veremos a continuación, la pila es utilizada tanto para pasar parámetros a funciones como para volver de ellas, si introducimos un valor en ella con PUSH dentro de una función y no lo sacamos antes de hacer el ret, nuestro programa continuará su ejecución en algún lugar de la memoria que no era al que debía volver. Es más, si nuestro programa debe volver a BASIC correctamente tras su ejecución, entonces es obligatorio que hagamos tantos PUSH como POP para que el punto final de retorno del programa al BASIC esté en la siguiente posición de la pila cuando nuestro programa acabe.
  • Ampliando la regla anterior, hay que tener cuidado con los bucles a la hora de hacer PUSH y POP.
  • Finalmente, no hay que asumir que SP tiene un valor correcto para nosotros. Tal vez tenemos planeado usar una zona de la memoria para guardar datos o subrutinas y el uso de PUSH y POP pueda sobreescribir estos datos. Si sabemos dónde no puede hacer daño SP y sus escrituras en memoria, basta con inicializar la pila al principio de nuestro programa a una zona de memoria libre (por ejemplo, ld sp, 49999, o cualquier otra dirección que sepamos que no vamos a usar). Esto no es obligatorio y muchas veces el valor por defecto de SP será válido, siempre que no usemos zonas de la memoria que creemos libres como “almacenes temporales”. Si usamos “variables” creadas en tiempo de ensamblado (definidas como DB o DW en el ensamblador) no deberíamos tener problemas, al menos con programas pequeños.

Veamos algunos ejemplos de “errores” con la pila. Empecemos con el típico PUSH del cual se nos olvida hacer POP:

    ; Este programa se colgará (probablemente, depende de BC)
    ; pero en cualquier caso, no seguirá su ejecución normal.
    push bc
    push de
 
    (código)
 
    pop de
    ret         ; En lugar de volver a la dirección de memoria
                ; a la que teníamos que volver, volveremos a
                ; la dirección apuntada por el valor de BC, que
                ; no hemos recogido de la pila.

También hay que tener cuidado con los bucles:

bucle:
    push bc         ; Nos queremos guardar BC
 
    (código que usa B)
 
    jr flag, bucle
    pop bc

En ese código hacemos múltiples PUSHes pero un sólo POP. Probablemente, en realidad, queremos hacer lo siguiente:

bucle:
    push bc         ; Nos queremos guardar BC
    (código)
 
    pop bc
    jr flag, bucle

O bien:

    push bc         ; Nos queremos guardar BC
 
bucle:
    (código)
 
    jr flag, bucle
    pop bc

Y una curiosidad al respecto de la pila y la sentencia CLEAR de BASIC: como ya vimos al principio del curso, lo que realiza la función CLEAR es cambiar el valor de la variable del sistema RAMTOP, lo que implica cambiar el valor de SP. Así, con CLEAR XXXX, ponemos la pila colgando de la dirección de memoria XXXX-1, asegurándonos de que BASIC no pueda hacer crecer la pila de forma que sobreescriba código máquina que hayamos cargado nosotros en memoria. Si, por ejemplo, vamos a cargar todo nuestro código a partir de la dirección 50000, en nuestro cargador BASIC haremos un CLEAR 49999, de forma que BASIC no podrá tocar ninguna dirección de memoria por encima de este valor.


La pila (stack) del Spectrum crece hacia abajo, por lo que tenemos 2 opciones para inicializar el valor de SP y definir la parte superior de la pila: ponerlo por encima de nuestro programa, o ponerlo por debajo.

Si lo ponemos por encima, hay que estar alerta de que el stack, al crecer (por llamadas a subrutinas, y por múltiples PUSHs/POPs) no machaque el final de nuestro programa o datos, es decir, que no crezca de forma que pusheemos valores llegando a sobreescribir zonas de memoria con código o datos de nuestro programa.

Si lo ponemos por debajo (con el ORG del programa por encima del inicio de la pila), ésta nunca pisará nuestro programa, pero podría (al “decrecer”) sobreescribir zonas de memoria con las variables de BASIC. Esto puede no importarnos si no usamos para nada llamadas a la ROM (o usamos llamadas de la ROM que no usan las variables del sistema), y si no usamos nosotros las propias variables del sistema y no pretendemos volver al BASIC tras la ejecución de nuestro programa.

Lo más sencillo es usar CLEAR x-1 (siendo x la dirección de inicio de nuestro programa) en el cargador BASIC y no tocar desde ASM el valor de SP, dejando que decrezca por debajo de nuestro programa. Nótese que si hacemos esto, y cargamos nuestro programa por ejemplo en 32768 ($6000), tendremos la pila en Contended Memory, algo que no es deseable como veremos a continuación.

Desde luego, la opción más segura es iniciar nuestro programa en una dirección de memoria tal que haya suficiente espacio para que la pila quepa bajo él (colgando de nuestra dirección de inicio), entre el inicio del programa y el fin de BASIC. Como ya vimos, para eso se recomendaba un valor mínimo de ORG 33500 o ORG 34000. Esto nos dejará un tamaño de la pila suficiente, con los primeros 708 bytes (ORG 33500) y 1232 bytes (ORG 34000) fuera de la Contended Memory. Todas estas consideraciones se explican en el capítulo dedicado a Consideraciones Avanzadas.

Otra opción segura es acotar en nuestro programa un espacio con DB / DS donde alojar la pila, en cualquier punto del mismo (al principio, al final, o en medio, no importa, siempre que no nos salgamos con PUSHes del espacio que le hemos dejado). En ese caso el problema es que ese “buffer” ocupa espacio en el ejecutable y por tanto “tiempo de carga”.

La última opción es poner SP a 0, con lo que decrecerá desde el final de la RAM. Recuerda que cuando hacemos PUSH, primero se decrementa SP y luego se guardan los valores en memoria, por lo que SP = 0 usará $fffe para el byte menos significativo y $ffff para el más significativo (recordemos que el Z80 es Low-Endian).

Pero si el target de nuestro programa es un modelo 128K y vamos a paginar, entonces el stack tiene que estar por debajo de $c000 ya que si no, al cambiar de banco lo perderíamos hasta volver al mismo (a menos que tengamos controlado que nuestro código no va a hacer ningún PUSH/pop hasta volver a poner el banco que tenía la pila, y además tengamos deshabilitadas las interrupciones).

Por lo tanto, mantenemos la recomendación que hicimos en los primeros capítulos del curso de dejar la pila por debajo de nuestro programa, con un ORG 33500 o 34000 para modelos 48K y 128K.


Al cambiar la ubicación de la pila en el Spectrum mediante la modificación del registro SP debemos tener una consideración especial cuando queramos ubicarla en la zona de memoria de 16KB entre 16384 y 32767.

Comenzando en la dirección de memoria 16384 está el área de videomemoria del Spectrum, donde se almacena en forma de datos numéricos el estado de los píxeles y colores de la pantalla. La ULA utiliza esta información para redibujar en la pantalla el contenido de esta videomemoria, a razón de 50 veces por segundo.

El haz de electrones del monitor se mueve de forma constante recorriendo la pantalla. La ULA, sincronizada con él, lee regularmente el contenido de la videomemoria para construir la señal de vídeo que debe representar dicho haz.

Cuando la ULA está dibujando la pantalla, necesita acceder a la memoria de video. Como la RAM no puede ser leída a la vez por 2 dispositivos (la ULA y la CPU), se da más prioridad a la ULA (porque el haz de electrones de la pantalla no puede detenerse y hay que dibujar la pantalla). De modo que cuando la ULA necesita leer un dato de la videoram, ésta bloquea temporalmente el acceso del Z80 a la memoria, ya que el dibujado de la pantalla tiene prioridad y se le debe proporcionar al haz de electrones la información de imagen conforme la necesita.

Cuando tanto la ULA como nuestro programa necesitan acceder a la memoria simultaneamente, es la ULA quien accede y el Z80 quien espera a que la ULA acabe. Esta espera puede agregar unos t-estados o ciclos extra de ejecución a las instrucciones que están tratando de leer o escribir cualquier dato en el bloque de 16KB que va desde 16384 hasta 32767.

Esto es lo que se conoce como “contented memory” o “memoria en contienda”.

Esto implica que las lecturas y escrituras de nuestro programa (ejecutado por el Z80) en la página de memoria de 16KB que va desde 16384 a 32767 se ven interrumpidas de forma constante por la ULA (aunque de forma transparente para nuestro programa), por lo que ubicar la pila en esta zona puede suponer una ralentización con respecto a ubicarla más arriba de la dirección 32768. Recuerda que cada operación PUSH y POP es, físicamente, un acceso de escritura y lectura a memoria, y las rutinas de nuestro programa harán, seguro, gran uso de ellas, además de los CALLs y RETs (PUSH PC + JP DIR / POP PC).

Por lo tanto, si establecemos la pila por debajo de nuestro programa, y tenemos nuestro programa en 32768, tendremos la pila en contended memory, lo cual implica que funcionará un poco más lenta en general que tener la pila por encima.

Esto no tiene por qué ser un problema (de hecho, puede ser inapreciable) salvo que tengamos que hacer rutinas muy precisas o que estemos desarrollando un juego y necesitemos arañar hasta el último ciclo de reloj. Además, el problema no es que un PUSH/POP sea unos ciclos de reloj más lento en “contended memory”, sino que será más lento A VECES (de forma impredecible). Unas veces (cuando esté la ULA leyendo la VRAM) tardará unos ciclos más en hacer push/pop y otras veces (cuando no esté leyendo la VRAM) tardará menos, y no podemos saber cuándo estamos en un caso y cuando en otro, por lo que no es seguro hacer cosas de precisión / sincronización con la pila ahí.

Otro punto que puede afectar a esto es si tenemos la pila en la contended memory y estamos haciendo un programa en C puro con Z88DK o en C con funciones en ensamblador, ya que el compilador de C pasa los parámetros de llamada de las funciones a través de la pila, por lo que se hace mucho uso de PUSH/POP. De hecho, el compilador Z88DK pone el inicio de la pila por defecto (creciendo habia abajo) en 65367 ($ff58) (reservando un total de 512 bytes para ella).

No debemos obsesionarnos con el hecho de que la pila esté en la memoria en contienda, pero está bien saberlo y tenerlo en cuenta.


Ya de por sí el lenguaje ensamblador es un lenguaje de listados “largos” y enrevesados, y donde teníamos 10 líneas en BASIC podemos tener 100 ó 1000 en ensamblador.

Lo normal para hacer el programa más legible es utilizar bloques de código que hagan unas funciones concretas y a los cuales podamos llamar a lo largo de nuestro programa. Esos bloques de código son las funciones o subrutinas.

Las subrutinas son bloques de código máquina a las cuales saltamos, hacen su tarea asignada, y devuelven el control al punto en que fueron llamadas. A veces, esperan recibir los registros con una serie de valores y devuelven registros con los valores resultantes.

Para saltar a subrutinas utilizamos la instrucción CALL, y estas deben de terminar en un RET.

El lector podría preguntar, ¿por qué no utilizar las instrucciones de salto JP y JR vistas hasta ahora? La respuesta es: debido a la necesidad de una dirección de retorno.

Veamos un ejemplo ilustrativo de la importancia de call/ret realizando una subrutina que se utilice JP para su llamada. Supongamos la siguiente “subrutina” sin RET:

; SUMA_A_10
;
; SUMA 10 a A y devuelve el resultado en B
;
; Nota: Modifica el valor de A
 
SUMA_A_10:
     add a, 10         ; A = A + 10
     ld b, a           ; B = A

Nuestra función/subrutina de ejemplo espera obtener en A un valor, y devuelve el resultado de su ejecución en B. Antes de llamar a esta rutina, nosotros deberemos poner en A el valor sobre el que actuar, y posteriormente interpretar el resultado (sabiendo que lo tenemos en B).

Pero, ¿cómo llamamos a las subrutinas y volvemos de ellas? Comencemos probando con JP:

    ld a, 35
    jp SUMA_A_10
volver1:
 
    (...)
 
; SUMA_A_10
; SUMA 10 a A y devuelve el resultado en B
; Nota: Modifica el valor de A
SUMA_A_10:
    add a, 10         ; A = A + 10
    ld b, a           ; B = A
    jp volver1        ; Volvemos de la subrutina

En este caso, cargaríamos A con el valor 35, saltaríamos a la subrutina, sumaríamos 10 a A (pasando a valer 45), haríamos B = 45, y volveríamos al lugar posterior al punto de llamada.

Pero … ¿qué pasaría si quisieramos volver a llamar a la subrutina desde otro punto de nuestro programa? Que sería inviable, porque nuestra subrutina acaba con un jp volver1 que no devolvería la ejecución al punto desde donde la hemos llamado, sino a “volver1”.

    ld a, 35
    jp SUMA_A_10
volver1:
 
    ld a, 50
    jp SUMA_A_10
                     ; Nunca llegariamos a volver aqui
    (...)
SUMA_A_10:
    add a, 10         ; A = A + 10
    ld b, a           ; B = A
    jp volver1        ; Volvemos de la subrutina

Para evitar ese enorme problema es para lo que se usa call y ret.


CALL es, en esencia, similar a jp, salvo porque antes de realizar el salto, introduce en la pila (PUSH) el valor del registro PC (Program Counter, o contador de programa), el cual (una vez leída y decodificada la instrucción CALL) apunta a la instrucción que sigue al CALL.

¿Y para qué sirve eso? Para que lo aprovechemos dentro de nuestra subrutina con RET. ret lee de la pila la dirección que introdujo call y salta a ella. Así, cuando acaba nuestra función, el ret devuelve la ejecución a la instrucción siguiente al call que hizo la llamada.

Son, por tanto, el equivalente ensamblador de GO SUB y RETURN en BASIC (o más bien se debería decir que GO SUB y RETURN son la implantación en BASIC de estas instrucciones del microprocesador).

call NN equivale a:
    PUSH PC
    jp NN

ret equivale a:
    POP PC

Veamos la aplicación de CALL y RET con nuestro ejemplo anterior:

    ld a, 35
    call SUMA_A_10
 
    ld a, 50
    call SUMA_A_10
 
    ld c, b
 
    (...)
 
SUMA_A_10:
    add a, 10         ; A = A + 10
    ld b, a           ; B = A
    ret               ; Volvemos de la subrutina

En esta ocasión, cuando ejecutamos el primer CALL, se introduce en la pila el valor de PC, que se corresponde exáctamente con la dirección de memoria donde estaría ensamblada la siguiente instrucción (ld a, 50). El CALL cambia el valor de PC al de la dirección de SUMA_A_10, y se continúa la ejecución dentro de la subrutina.

Al acabar la subrutina encontramos el RET, quien extrae de la pila el valor de PC anteriormente introducido, con lo que en el siguiente ciclo de instrucción del microprocesador, el Z80 leerá, decodificará y ejecutará la instrucción ld a, 50, siguiendo el flujo del programa linealmente desde ahí. Con la segunda llamada a CALL ocurriría lo mismo, pero esta vez lo que se introduce en la pila es la dirección de memoria en la que está ensamblada la instrucción ld c, b. Esto asegura el retorno de nuestra subrutina al punto adecuado.

Al hablar de la pila os contamos lo importante que era mantener la misma cantidad de PUSH que de POPs en nuestro código. Ahora entenderéis por qué: si dentro de una subrutina hacéis un PUSH que no elimináis después con un POP, cuando lleguéis al RET éste obtendrá de la pila un valor que no será el introducido por CALL (sino el introducido por el PUSH), y saltará a esa dirección incorrecta. Por ejemplo:

    call SUMA_A_10
    ld c, b              ; Esta dirección se introduce en la pila con call
 
SUMA_A_10:
    ld de, $0000
    push de
    add a, 10
    ld b, a
    ret                  ; ret no sacará de la pila lo introducido por call
                         ; sino "0000", el valor que hemos pulsado nosotros.

Aquí RET sacará de la pila 0000h, en lugar de la dirección que introdujo CALL, y saltará al inicio del a ROM, produciendo un bonito reset.

Ni CALL ni RET afectan a la tabla de flags del registro F.

                        Flags
   Instrucción       |S Z H P N C|
 ----------------------------------
 call NN             |- - - - - -|
 ret                 |- - - - - -|


La instrucción RST es un resquicio de la compatibilidad que el Z80 tiene con el procesador 8080.

RST ejecuta un CALL como el que ya hemos visto, pero permitiendo un salto sólo a una serie de direcciones en el bloque desde la dirección 0 a la dirección 255. RST $NN es, literalmente, un call $00NN.

Las siguientes instrucciones son equivalentes en cuanto a resultado de la ejecución:

CALL RST
call $0000 rst $00
call $0008 rst $08
call $0010 rst $10
call $0018 rst $18
call $0020 rst $20
call $0028 rst $28
call $0030 rst $30
call $0038 rst $38

La principal ventaja de RST es que ocupa un sólo byte (cada uno de los 8 RST tiene su propio opcode de 1 byte asociado).

  rst 0      ; Opcode C7 (11 T-estados).
  rst 8      ; Opcode CF (11 T-estados).
  rst 10h    ; Opcode D7 (11 T-estados).
  rst 18h    ; Opcode DF (11 T-estados).
  rst 20h    ; Opcode E7 (11 T-estados).
  rst 28h    ; Opcode EF (11 T-estados).
  rst 30h    ; Opcode F7 (11 T-estados).
  rst 38h    ; Opcode FF (11 T-estados).

Por contra, call ocupa 3 bytes en memoria ($cd NN NN).

La ventaja de tener estas instrucciones de salto de 1 sólo byte es que un programador puede colocar en estas direcciones rutinas que sean muy comunes de usar ($0008, $0010, etc), ahorrando 2 bytes en cada llamada que después se hagan a ellas.

En el caso del Spectrum, estas direcciones de memoria caen en la ROM (no así en otros ordenadores que tienen la ROM al final, por ejemplo), por lo que no las podemos aprovechar en nuestros programas, aunque ya lo hicieron por nosotros los diseñadores de la ROM del Spectrum al colocar en esas direcciones de salto puntos de entrada a rutinas tan comunes como rst 16 (rst $10) que sirve, como ya hemos visto, para imprimir un carácter.


Una de las peculiaridades de call y ret es que tienen instrucciones condicionales con respecto al estado de los flags, igual que jp cc o jr cc, de forma que podemos condicionar el SALTO (call) o el retorno (ret) al estado de un determinado flag.

Para eso, utilizamos las siguientes instrucciones:


  • call flag, NN : Salta sólo si FLAG está activo.
  • ret flag : Vuelve sólo si FLAG está activo.


Por ejemplo, supongamos que una de nuestras subrutinas tiene que comprobar que uno de los parámetros que le pasamos, BC, no sea 0.

; Copia_Pantalla:
;
; Entrada:
;             HL = direccion origen
;             DE = direccion destino
;             BC = bytes a copiar
;
Copia_Pantalla:
 
    ; lo primero, comprobamos que BC no sea cero:
    ld a, b
    or c                           ; Hacemos un OR de B sobre C
                                   ; Si BC es cero, activará el flag Z
    ret z                          ; Si BC es cero, volvemos sin hacer nada
 
    (más código)
    ; Aquí seguiremos si BC no es cero, el ret no se habrá ejecutado.

Del mismo modo, el uso de CALL condicionado al estado de flags (CALL Z, CALL NZ, CALL M, CALL P, etc) nos permitirá llamar o no a funciones según el estado de un flag.

Al igual que CALL y RET, sus versiones condicionales no afectan al estado de los flags.

                        Flags
   Instrucción       |S Z H P N C|         Pseudocodigo
 -----------------------------------------------------------
 call cc, NN         |- - - - - -|        IF cc call NN
 ret cc              |- - - - - -|        IF cc ret


Ahora que ya sabemos crear rutinas y utilizarlas, vamos a ver los 3 métodos que hay para pasar y devolver parámetros a las funciones.


Este método consiste en modificar unos registros concretos antes de hacer el CALL a nuestra subrutina, sabiendo que dicha subrutina espera esos registros con los valores sobre los que actuar. Asímismo, nuestra rutina puede modificar alguno de los registros con el objetivo de devolvernos un valor. Si modifica algún registro en el transcurso de la rutina, lo normal es preservarlo con un PUSH

Este método es el más habitual en los programas en ensamblador siempre y cuando no tengamos más parámetros de entrada a la rutina que registros existentes en el Z80.

Por ejemplo:

;--------------------------------------------------------------
; Mult_HL_DE: Multiplica DE*BC
;
; Entrada:        DE: Multiplicando,
;                 BC: Multiplicador
; Salida:         HL: Resultado.
; Modifica:       Ningun registro aparte de HL
;--------------------------------------------------------------
Mult_HL_DE:
    push af             ; Preservamos AF porque F se va a modificar
    push bc             ; Preservamos BC porque su valor se pierde
    ld hl, 0
 
multiloop_01:
    add hl, de
    dec bc
    ld a, b
    or c
    jr nz, multiloop_01
 
    pop bc              ; Rescatamos el valor de BC
    pop af              ; Rescatamos el valor de AF
    ret

Antes de hacer la llamada a Mult_HL_DE, tendremos que cargar en DE y en BC los valores que queremos multiplicar, de modo que si estos valores están en otros registros o en memoria, tendremos que moverlos a DE y BC.

Además, sabemos que la salida nos será devuelta en HL, con lo que si dicho registro contenía algún valor importante y que no debemos perder en el código que llama a la rutina, deberemos preservarlo previamente.

Con este tipo de funciones resulta importantísimo realizarse cabeceras de comentarios explicativos, que indiquen:

a.- Qué función realiza la subrutina.
b.- Qué registros espera como entrada.
c.- Qué registros devuelve como salida.
d.- Qué registros modifica además de los de entrada y salida.

Con este tipo de paso de parámetros tenemos el mayor ahorro y la mayor velocidad: no se accede a la memoria, no se usa la pila (salvo para preservar parámetros), pero por contra tenemos que tener un gran control del “contexto” de la llamada. Tendremos que saber en cada momento qué parámetros de entrada y de salida utiliza (de ahí la importancia del comentario explicativo o de nuestra documentación del programa, al que acudiremos más de una vez cuando no recordemos en qué registros teníamos que pasarle los datos de entrada), y asegurarnos de que ninguno de los registros “extra” que modifica están en uso antes de llamar a la función, puesto que se verán alterados.

Como hemos visto, si queremos preservar el valor de los registros modificados por la rutina, siempre podemos poner una serie de PUSH y POP en su inicio y final, al estilo:

MiFuncion:
    push bc
    push de      ; Nos guardamos sus valores
 
    (...)
 
    pop de
    pop bc       ; Recuperamos sus valores
    ret

En funciones que no sean críticas en velocidad, es una buena opción porque no tendremos que preocuparnos por el estado de nuestros registros durante la ejecución de la subrutina: al volver de ella tendrán sus valores originales (excepto aquellos de entrada y salida que consideremos necesarios).

Habrá casos en que no será necesario ponerlos. Si por ejemplo tenemos una función que ejecutamos al inicio del programa para, por ejemplo, precalcular algunos datos, no necesitaremos que preserve registros ya que sus valores al llamarlas no son importantes. También, en funciones muy críticas y que necesitan ser rápidas, en ocasiones no preservaremos los registros en ellas y lo que haremos será cerciorarnos en el código que hace la llamada que estas no modifican ningún registro que sea importante para nosotros en esa parte del código.

No nos olvidemos de que en algunos casos (muy pocos normalmente) podemos usar el juego de registros alternativos (ex af, af', EXX) para evitar algún PUSH o POP. En el caso del ejemplo anterior, podríamos haber reemplazado el push af y pop af (11 y 10 ciclos de reloj respectivamente, 21 ciclos en total) por dos ex af, af' (4 ciclos cada uno, 8 en total, mucho más eficiente).


Aunque no es una opción especialmente rápida, el uso de variables o posiciones de memoria para pasar y recoger parámetros de funciones es bastante efectivo y sencillo. Nos ahorra el uso de muchos registros, y hace que podamos usar dentro de las funciones prácticamente todos los registros. Se hace especialmente útil en este caso usando el juego de registros alternativos para compensar el uso de la memoria con el evitar PUSHs/POPs para preservar registros.

Por ejemplo:

    ld a, 10
    ld (x), a
    ld a, 20
    ld (y), a
    ld bc, 40
    ld (size), bc      ; Parametros de entrada a la funcion
    call MiFuncion
    (...)
 
MiFuncion:
    exx                ; Preservamos TODOS los registros
 
    ld a, (x)
    ld b, a
    ld a, (y)
    ld bc, (size)      ; Leemos los parametros
 
    (... código ...)
 
    ld (salida), a     ; Devolvemos un valor
    exx
    ret
 
x      DB  0
y      DB  0
size   DW  0
salida DB  0

Este es un ejemplo exagerado donde todos los parámetros se pasan en variables, pero lo normal es usar un método mixto entre este y el anterior, pasando cosas en registros excepto si nos quedamos sin ellos (por que una función requiere muchos parámetros, por ejemplo), de forma que algunas cosas las pasamos con variables de memoria.

Este método se puede pues utilizar en conjunción con el anterior pasando algunos parámetros en registros y otros por memoria, ya sean variables “generales/globales” del programa, variables del sistema, o “variables locales” que hemos definido bajo la función como uno o varios DB/DW exclusivos para pasar parámetros a la rutina.

La ventaja del paso de parámetros por memoria es que podemos utilizar las rutinas desde BASIC, POKEando los parámetros en memoria y llamando a la rutina con RANDOMIZE USR DIRECCION.


El tercer método es el sistema que utilizan los lenguajes de alto nivel para pasar parámetros a las funciones: el apilamiento de los mismos. Este sistema no se suele utilizar en ensamblador, pero vamos a comentarlo de forma que os permita integrar funciones en ASM dentro de programas escritos en C, como los compilables con el ensamblador Z88DK.

En C (y en otros lenguajes de programación) los parámetros se insertan en la pila en el orden en que son leídos. La subrutina después lee los valores sin desapilarlos, usando el valor de SP para acceder a ellos. En ensamblador no es normal utilizar este método a menos que tengamos muchos parámetros, no nos quepan en registros y que queramos ir rescatándolos de la pila en el punto de la función que nos interese (sea con el valor de SP o con POP).

En ese caso, simplemente apilamos los parámetros con PUSH y dentro de la rutina los vamos recogiendo con POP:

Veamos unos ejemplos:

    push bc        ; coordenada X
    push de        ; coordenada Y
    push hl        ; direccion grafico
    call Rutina
    (...)
 
Rutina:
    pop hl         ; HL = coordenada Y
 
    ; (trabajamos con HL)
 
                   ; Ahora recogemos el parametro 2,
                   ; en HL o en cualquier otro registro
    pop hl         ; HL = coordenada X
 
    ; (hacemos calculos con HL)
 
    pop de         ; HL = direccion grafico
 
    ret

Nótese que hacemos PUSH de los 3 parámetros con 3 registros concretos pero que luego no hacemos POP de esos mismos registros. Hacer eso sería lo mismo que pasarse los parámetros en esos registros sin usar la pila. Si estamos usando la pila, es porque tenemos más parámetros que registros, o porque necesitamos extraer cada parámetro en el punto del programa donde nos interese y en un registro concreto. Lo importante es que antes del RET hayamos sacado de la pila todo lo que se introdujo, para que lo siguiente que esté presente en la pila sea la dirección de retorno para RET.

También podemos usar acceso directo a memoria mediante el valor de SP saltándonos los 2 bytes de la dirección de retorno introducida en la pila por el CALL, como hace el compilador de C Z88DK, pero en ese caso necesitaremos antes de salir de la rutina hacer un POP de todos los parámetros introducidos:

    push bc        ; coordenada X
    push de        ; coordenada Y
    call Rutina
 
Rutina:
    ld hl, 2       ; 2 bytes = direccion de retorno introducida por call
    add hl, sp     ; Ahora SP apunta al ultimo parametro metido
                   ; en la pila por el compilador (valor de Y)
 
    ld c, (hl)
    inc hl
    ld b, (hl)
    inc hl         ; Ahora BC = Y
 
    ld e, (hl)
    inc hl
    ld d, (hl)
    inc hl         ; Ahora, DE = X
 
    ;;; (ahora hacemos lo que queramos en asm)
 
    pop de
    pop bc          ; Tambien podriamos simplemente restar N a SP

Los parámetros de 8 bits en este caso se tienen que pasar como 16 bits con la parte alta a 0, ya que la pila usa 2 bytes en PUSH y POP. Si usamos POP para acceder a los datos en la pila, simplemente ignoramos la parte alta del registro recuperado. Si usamos el valor de SP para acceder a la pila, simplemente tenemos que avanzar HL para saltarnos la parte alta de cada valor 16 bits:

Rutina:
    ld hl, 2            ; 2 bytes = direccion de retorno introducida por call
    add hl, sp          ; Ahora SP apunta al ultimo parametro metido en pila
 
    ld a, (hl)          ; Aquí tenemos nuestro dato de 8 bits (Y)
    ld b, a
    inc hl
    inc hl              ; La parte alta del byte no nos interesa
 
    ld a, (hl)          ; Aquí tenemos nuestro dato de 8 bits (X)
    ld c, a
                        ; Aqui no necesitamos mas inc hl, no hay mas parametros
 
    ; Nuestra rutina empieza a trabajar aquí

Por contra, para devolver valores no se utiliza la pila (dado que no podemos tocarla debido al RET), sino que se utilizarán registros o direcciones de memoria.

Como hemos comentado, en programas íntegramente escritos en ensamblador usaremos este método muy raras veces.


Usar subrutinas es mucho más importante de lo que parece a simple vista: nos permite organizar el programa en unidades o módulos funcionales que cumplen una serie de funciones específicas, lo que hace mucha más sencilla su depuración y optimización.

Si en el menú de nuestro juego estamos dibujando una serie de sprites móviles, y también lo hacemos a lo largo del juego, resulta absurdo “construir” 2 bloques de código, uno para mover los sprites del menú y otro para los del juego. Haciendo esto, si encontramos un error en una de las 2 rutinas, o realizamos una mejora, deberemos corregirlo en ambas.

Por contra, si creamos una subrutina, digamos, DrawSprite, que podamos llamar con los parámetros adecuados en ambos puntos del programa, cualquier cambio, mejora o corrección que realicemos en DrawSprite afectará a todas las llamadas que le hagamos. También reducimos así el tamaño de nuestro programa (y con él el tiempo de carga del mismo), las posibilidades de fallo, y la longitud del listado (haciéndolo más legible y manejable).

Aunque no sea el objetivo de esta serie de artículos, antes de sentarse a teclear, un buen programador debería coger un par de folios de papel y hacer un pequeño análisis de lo que pretende crear. Este proceso, la fase de diseño, define qué debe de hacer el programa y, sobre todo, una división lógica de cuáles son las principales partes del mismo. Un sencillo esquema en papel, un diagrama de flujo, identificar las diferentes partes del programa, etc.

El proceso empieza con un esbozo muy general del programa, que será coincidente con la gran mayoría de los juegos: inicialización de variables, menú (que te puede llevar bien a las opciones o bien al juego en sí), y dentro del juego, lectura de teclado/joystick, trazado de la pantalla, lógica del juego, etc.

Después, se teclea un programa vacío que siga esos pasos, pero que no haga nada; un bucle principal que tenga un aspecto parecido a:

BuclePrincipal:
    call LeerTeclado             ; o Leer_Teclado
    call LogicaJuego             ; o Logica_Juego
    call ComprobarEstado         ; o Comprobar_Estado
    jp BuclePrincipal            ; o Bucle_Principal
 
LeerTeclado:
    ret
 
LogicaJuego:
    ret
 
ComprobarEstado:
    ret

Tras esto, ya tenemos el “esqueleto del programa”. Y ahora hay que rellenar ese esqueleto, y la mejor forma de hacerlo es aprovechar esa “modularidad” que hemos obtenido con ese diseño en papel.

Por ejemplo, supongamos que nuestro juego tiene que poder dibujar sprites y pantallas hechas a bases de bloques que se repiten (tiles). Gracias a nuestro diseño, sabemos que necesitamos una rutina que imprima un sprite, una rutina que dibuje un tile y una rutina que dibuje una pantalla llena de tiles.

Pues bien, creamos un programa en ASM nuevo, desde cero, y en él creamos una función DrawSprite que acepte como parámetros la dirección origen de los datos del Sprite, y las posiciones X e Y donde dibujarlo, y la realizamos. En este nuevo programa, pequeño, sencillo de leer, realizamos todo tipo de pruebas:

    ORG 50000
 
    ; Probamos de diferentes formas nuestra rutina
    ld b, 10
    ld c, 15
    ld hl, sprite
    call DrawSprite
    ret
 
; Rutina DrawSprite
; Acepta como parametros ... y devuelve ...
DrawSprite:
    (aquí el código)
    ret
 
sprite DB 0,0,255,123,121,123,34, (etc...)
 
    END 50000

Gracias a esto, podremos probar nuestra nueva rutina y trabajar con ella limpiamente y en un fichero de programa pequeño. Cuando la tenemos lista, basta con copiarla a nuestro programa “principal” y ya sabemos que la tenemos disponible para su uso con call.

Así, vamos creando diferentes rutinas en un entorno controlado y testeable, y las vamos incorporando a nuestro programa. Si hay algún bug en una rutina y tenemos que reproducirlo, podemos hacerlo en nuestros pequeños programas de prueba, evitando el típico problema de tener que llegar a un determinado punto de nuestro programa para chequear una rutina, o modificar su bucle principal para hacerlo.

Además, el definir de antemano qué tipo de subrutinas necesitamos y qué parámetros deben aceptar o devolver permite trabajar en equipo. Si sabes que necesitarás una rutina que dibuje un sprite, o que lea el teclado y devuelva la tecla pulsada, puedes decir los registros de entrada y los valores de salida que necesitas, y que la realice una segunda persona y te envíe la rutina lista para usar.

En ocasiones una excesiva desgranación del programa en módulos más pequeños puede dar lugar a una penalización en el rendimiento, aunque no siempre es así. Por ejemplo, supongamos que tenemos que dibujar un mapeado de 10×10 bloques de 8×8 pixeles cada uno. Si hacemos una función de que dibuja un bloque de 8×8, podemos llamarla en un bucle para dibujar nuestros 10×10 bloques.

Hay gente que, en lugar de esto, preferirá realizar una función específica que dibuje los 10×10 bloques dentro de una misma función. Esto es así porque de este modo te evitas 100 calls (10×10) y sus correspondientes RETs, lo cual puede ser importante en una rutina gráfica que se ejecute X veces por segundo. Por supuesto, en muchos casos tendrán razón, en ciertas ocasiones hay que hacer rutinas concretas para tareas concretas, aún cuando puedan repetir parte de otro código que hayamos escrito anteriormente, con el objetivo de evitar llamadas, des/apilamientos u operaciones innecesarias en una función crítica.

Pero si, por ejemplo, nosotros sólo dibujamos la pantalla una vez cuando nuestro personaje sale por el borde, y no volvemos a dibujar otra hasta que sale por otro borde (típico caso de juegos sin scroll que muestran pantallas completas de una sóla vez), vale la pena el usar funciones modulares dado que unos milisegundos más de ejecución en el trazado de la pantalla no afectarán al desarrollo del juego.

Al final hay que llegar a un compromiso entre modularidad y optimización, en algunos casos nos interesará desgranar mucho el código, y en otros nos interesará hacer funciones específicas. Y esa decisión no deja de ser, al fin y al cabo, diseño del programa.

En cualquier caso, el diseño nos asegura que podremos implementar nuestro programa en cualquier lenguaje y en cualquier momento. Podremos retomar nuestros “papeles de diseño” 3 meses después y, pese a no recordar en qué parte del programa estábamos, volver a su desarrollo sin excesivas dificultades.

Una de las cosas más complicadas de hacer un juego es el pensar por dónde empezar. Todo este proceso nos permite empezar el programa por la parte del mismo que realmente importa. Todos hemos empezado alguna vez a realizar nuestro juego por el menú, perdiendo muchas horas de trabajo para descubrir que teníamos un menú, pero no teníamos un juego, y que ya estábamos cansados del desarrollo sin apenas haber empezado.

Veamos un ejemplo: suponiendo que realizamos, por ejemplo, un juego de puzzles tipo Tetris, lo ideal sería empezar definiendo dónde se almacenan los datos del area de juego, hacer una función que convierta esos datos en imágenes en pantalla, y realizar un bucle que permita ver caer la pieza. Después, se agrega control por teclado para la pieza y se pone la lógica del juego (realización de líneas al tocar suelo, etc).

Tras esto, ya tenemos el esqueleto funcional del juego y podemos añadir opciones, menúes y demás. Tendremos algo tangible, funcional, donde podemos hacer cambios que implican un inmediato resultado en pantalla, y no habremos malgastado muchas horas con un simple menú.

Por otra parte, el diseñar correctamente nuestro programa y desgranarlo en piezas reutilizables redundará en nuestro beneficio no sólo actual (con respecto al programa que estamos escribiendo) sino futuro, ya que podremos crearnos nuestras propias “bibliotecas” de funciones que reutilizar en futuros programas.

Aquella rutina de dibujado de Sprites, de zoom de pantalla o de compresión de datos que tanto nos costó programar, bien aislada en una subrutina y con sus parámetros de entrada y salida bien definidos puede ser utilizada directamente en nuestros próximos programas simplemente copiando y pegando el código correspondiente.

Más aún, podemos organizar funciones con finalidades comunes en ficheros individuales. Tendremos así nuestro fichero / biblioteca con funciones gráficas, de sonido, de teclado/joystick, etc. El ensamblador Pasmo nos permite incluir un fichero en cualquier parte de nuestro código con la directiva INCLUDE.

Así, nuestro programa en ASM podría comenzar (o acabar) por algo como:

INCLUDE "graficos.asm"
INCLUDE "sonido.asm"
INCLUDE "teclado.asm"
INCLUDE "datos.asm"

También podemos utilizar este sistema para los programas de prueba y testeo de las funciones que vamos realizando para el programa principal. Así, podemos verificar con un sencillo programa que incluya algunos .asm del juego si la rutina que acabamos de crear funciona correctamente.

La organización del código en bibliotecas de funciones contribuye a reducir fallos en la codificación, hacer más corto el “listado general del programa”, y, sobre todo, reduce el tiempo de desarrollo.


  • cursos/ensamblador/lenguaje_4.txt
  • Última modificación: 22-01-2024 07:54
  • por sromero